PERLFORM

Section: Perl Programmers Reference Guide (7)
Updated: 2003-11-25
Index Return to Main Contents
 

NAME

perlform - Perl 格式  

DESCRIPTION 描述

Perl的一些内部机制、可以帮助我们产生一份简单的格式化图表。经过perl的处理,你列印的格式可以接近於你所见的外貌。它可以记录如你现在正处在哪个页面,每个页面的行数与何时列印出页面的标题。关键字,format() 格式函数与write()执行函数是直接引自FORTRAN语法。详情可参阅 perlfunc。幸运的是列印的格式可读性又有所提高。几乎类似BASIC 的PRINT USING。可以把它想象为简单的 nroff(1).

有如子程序与包一样,格式只是语句的声明,而不是执行调用。故它可以放在程式的任何位置(一般最好是把它们集中在一块)。与perl的其它变量名字类型不同, 格式命名有别於一般的独自的定义。也就是说,你有一个名为Foo的函数,它与另一个格式名称为Foo的东西是完全不同。但是缺省的格式名称与有关连的文件句柄可用相同的名字。所以缺省的输出格式名称STDOUT,它的文件句柄名称就是STDOUT。而对缺省格式名称TEMP,它的文件句柄名称也可以是TEMP。虽然名称一样但两者并不相同。

输出格式的语法如下:

    format NAME =
    FORMLIST
    .

如省略格式名称,格式名称将以标准输出STDOUT命名。而格式项目将包括了好几个连续横行。每一行属於下列叁种型态之一:

1.
注释(comment), 以符号“#”置於每行的开头。
2.
图案行(picture line),规定了单一行的格式化外观。
3.
参数行, 提供一些数值以对应前面的图案行。

图案行的输出效果就与我们看到的一样,除了某些值域栏位会给相对应数值取代外,每个输入栏位都以一个@或 ^ 控制符开头。这些单行内的控制符不能做任何窜改取代(勿与数组变量@混淆)。@栏位是属於正常形态的栏位,而^栏位则用来表示可以输入多行文字。至於该栏位则由< > 或 | 符号跟随其後指定向左、右、或居中对齐。并同时跟据该符号的数目,输入指定资料的长度。如变量内容超过限定长度、格式列印时会自动删除多馀的部份。

另一种指定向右对齐方式,是使用#符号来指定一个数字栏位。如此可方便小数点定位。如果输入值里还包含一个换行字元(,则仅列印出该换行字元前的资料。最後图案行出现的@*这个特别符号标记,可以用来列印多行并且不被截掉的数值。

接下来的一行、是跟据图案行里的值域栏位输入相应的数值。如果是利用运算式提供数值的话、必须以逗号分隔。因为所有的表示法都会被当成一个串连内容再行处理。所以一个单一的串列表示法也可产生多个串列资料。如果表示法是利用括号围起,可能会展开好几行。若想如是安排,第一行的第一个单字必须是以左括号开始。如果运算式内有小数点的数字类型须要处理、同时图案行的相关符号也指出小数位须列印出来(除了图案行内的包含小数点"."的数字控制符号#外)。小数点列印出的外貌, 以当地的运行版本决定(LC_NUMERIC locale)。也就是说、在德文地区使用小数格示输出时、小数点的显示将是","而非"."。相关资料请参考 perllocale 与 "警告"

图案行里的栏位如果以^控制符开头、格式将会作特殊化处理。如果该栏位是注解栏位又没定义其值、栏位将以空白取代。若是其它型态、则视为一种填补资料的状态。 在此、我们不能随便填入任意表示法进去。相反、必须以相关的变量输入字串内容。perl会尽量将文字放入该栏位、然後把字串的前面部份删去。当你下次使用该字串变量时、可以使用後面的字串部份(换句话说、在执行write函数时、字串变量的内容是会改变的)。正常情况下、你必须使用一类似垂直状的堆块来放置要输入的文字、以便整齐列印出一柱状文字。如你列印的文字太长、想以"..."取代过长的文字时、你可以藉由更改 $: 变量值来取代分隔字元。也就是当你使用ENGLISH模块时的 $FORMAT_LINE_BREAK_CHARACTERS的意思。

使用^符号栏位可产生不定长度的记录栏位。如果要列印的文字很短、你想压缩掉文字後的空白、请在想压缩掉的空白地方加上一个"~"控制符号。如果重复使用两个"~"符号、则该行会被重复列印、直到该栏位的所有文字列印完毕为止 (如你同时使用"@"值域栏位的话、切记每次要输入不同的数值)。

列印格示标题的缺省处理方法、是将正使用的格式名称後加上_TOP字样既可。其内容将会列印至每页的开头部份。请参考 perlfunc/write 函数

例如:

 # a report on the /etc/passwd file
 format STDOUT_TOP =
                         Passwd File
 Name                Login    Office   Uid   Gid Home
 ------------------------------------------------------------------
 .
 format STDOUT =
 @<<<<<<<<<<<<<<<<<< @||||||| @<<<<<<@>>>> @>>>> @<<<<<<<<<<<<<<<<<
 $name,              $login,  $office,$uid,$gid, $home
 .

 # a report from a bug report form
 format STDOUT_TOP =
                         Bug Reports
 @<<<<<<<<<<<<<<<<<<<<<<<     @|||         @>>>>>>>>>>>>>>>>>>>>>>>
 $system,                      $%,         $date
 ------------------------------------------------------------------
 .
 format STDOUT =
 Subject: @<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
          $subject
 Index: @<<<<<<<<<<<<<<<<<<<<<<<<<<<< ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        $index,                       $description
 Priority: @<<<<<<<<<< Date: @<<<<<<< ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
           $priority,        $date,   $description
 From: @<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
       $from,                         $description
 Assigned to: @<<<<<<<<<<<<<<<<<<<<<< ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
              $programmer,            $description
 ~                                    ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                                      $description
 ~                                    ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                                      $description
 ~                                    ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                                      $description
 ~                                    ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                                      $description
 ~                                    ^<<<<<<<<<<<<<<<<<<<<<<<...
                                      $description
 .

我们也有可能在同一个输出管道同时使用print 与 write函数。但使用时、必须修改$-的特殊内置变量值(使用English模块的话、则是使用$FORMAT_LINES-LEFT变量)。

Format Variables 格式变量

当前的格式名称一向都是存放於$~这个特殊变量内($FORMAT_NAME),而每页的开头格式则存放在$^($FORMAT-TOP_NAME),输出页为$%($FORMAT_PAGE_NUMBER),每页行数是$= ($FORMAT_LINE_PER_PAGE),自动输出格式是放在$|($OUTPUT_AUTOFLUSH)、要输出到每页开头部份的字串存放在$^L ($FORMAT-FORMFEED)。这些变量的有效范围,都是以某一个文件句柄为单元。因此、你必须调用select()函数来调用适当的文件句柄来改变变量内容。

    select((select(OUTF),
            $~ = "My_Other_Format",
            $^ = "My_Top_Format"
           )[0]);

难看吧!这就是一般用法。如此一来、你至少可用临是变量来存放前一个文件句柄。事实上、这已是较好的作法,除了可读性提高外、也提供你一个位置暂停程式的执行,方变你一次到位除错。

    $ofh = select(OUTF);
    $~ = "My_Other_Format";
    $^ = "My_Top_Format";
    select($ofh);

如果你使用English模块,你甚至可以输入英文变量名称

    use English '-no_match_vars';
    $ofh = select(OUTF);
    $FORMAT_NAME     = "My_Other_Format";
    $FORMAT_TOP_NAME = "My_Top_Format";
    select($ofh);

但你还是要调用select()函数。因此我们建议你用FileHandle模块。现在你可用小写英文字母的格式名称来处理这些特殊变量。

    use FileHandle;
    format_name     OUTF "My_Other_Format";
    format_top_name OUTF "My_Top_Format";

好多了吧!  

NOTES

因为数值行的内容可能保括任何的表示法 (我们指的是 @ 栏位而非 ^ 栏位)。因此你可使用其它函数、建立更加复杂的处理方法。好像使用 printf 函数、或自己定义的函数。列如:

    format Ident =
        @<<<<<<<<<<<<<<<
        &commify($n)
    .

在栏位输入真正的@ 或^符号:

    format Ident =
    I have an @ here.
            "@"
    .

将整行字置中对齐:

    format Ident =
    @|||||||||||||||||||||||||||||||||||||||||||||||
            "Some text line"
    .

我们并无任何内建的方法让你指定如、某个栏位要对齐该页面最右等诸如此类事项。但你仍然能列印出你想要的格式。跟据目前页面直行数目,调用eval()函数来处理它:

    $format  = "format STDOUT = \n"
             . '^' . '<' x $cols . "\n"
             . '$entry' . "\n"
             . "\t^" . "<" x ($cols-8) . "~~\n"
             . '$entry' . "\n"
             . ".\n";
    print $format if $Debugging;
    eval $format;
    die [email protected] if [email protected];

它可能列印出下列格式外貌:

 format STDOUT =
 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
 $entry
         ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<~~
 $entry
 .

下面是一个有点类似fmt(1)的小程式:

 format =
 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
 $_

 .

 $/ = '';
 while (<>) {
     s/\s*\n\s*/ /g;
     write;
 }


Footers 页脚

虽然我们有$FORMAT_TOP_NAME来记录每页开头部份的格式,却没有一个相对应的方法来自动指定每页的底部格式。问题是、我们并不知到某个格式资料可能会多大,除非你真的去执行它。这是我们将来要处理的重点之一。

这是一个暂时的应用方案 如果你有一个固定大小的页脚、你可在每次调用write函数前检查变量$FORMAT_LINES_LEFT,然後自行印出该资料。

还有一个方法,就是开启一个管道。调用open(MYSELF,”|-”) (参考 perlfunc/open() 函数)。并调用write函数把资料输往MYSELF、而不是标准输出STDOUT。然後利用子串列的标准输入、来重新处理每页开头或结尾所要附加的资料部份。这虽不方便,但还是可办到的。

Accessing Formatting Internals 格式处理的核心

至於低阶格式的机制,你可调用formlin()函数直接处理$^A变量($ACCUMUNATOR)。

例如:

    $str = formline <<'END', 1,2,3;
    @<<<  @|||  @>>>
    END

    print "Wow, I just stored `$^A' in the accumulator!\n";

或是设计一个子程式swrite()。它对于 write 的脚色相当于sprint 对于 print。

    use Carp;
    sub swrite {
        croak "usage: swrite PICTURE ARGS" unless @_;
        my $format = shift;
        $^A = "";
        formline($format,@_);
        return $^A;
    }

    $string = swrite(<<'END', 1, 2, 3);
 Check me out
 @<<<  @|||  @>>>
 END
    print $string;

 

WARNINGS 警告

不当处理显示结束格示内容的点操作符号、有时也会同时影响你的网络的电邮功能(跟据过往经验、错误是必然而不能避免)。如果使用电邮输出格式内容、你应先处理好结束格式点操作符位置。切勿放置於左边界、以免被SMTP截去。

局部变量(引用”my”定义变量)、在调用格式化输出时不会被察觉。除非在使用局部变量的串程内另行定义(5.001版本前并没有局部变量一词)。

格式输出是 perl 语言里维一受制於编程使用地区的部分。如果当前的使用地区使用LC_NUMERIC,那小数点符号的格式化输出必以当地方式显示。perl 不会理会当地的所须格式,除非你调用了 use locale。但格式列印又不受控於use locale。因为locale 它只在使用的块内有效。同时跟据历史原因、格式的作用域不仅包括在块内。进一步详情参阅 perllocale 本地化文档。

格式输出时、程式串内的空白符号 , 相当於一个空白单元。所以你可以想像格式列印相当於先处理变量:

 $value =~ tr/\n\t\f/ /;

除非图案行已定义、馀下的空白符号 将强制性另印新行。  

中文版维护人

小高 <[email protected]>  

中文版最新更新

2001年12月9日星期日  

中文手册页翻译计划

http://cmpp.linuxforum.net


 

Index

NAME
DESCRIPTION 描述
NOTES
WARNINGS 警告
中文版维护人
中文版最新更新
中文手册页翻译计划

This document was created by man2html, using the manual pages.
Time: 13:12:52 GMT, December 24, 2015